metal detector using arduino

metal detector using Arduino

metal detector code, copy and pest 


//*****" FUTURE TECHNOLOGY RC" (YOUTUBE CHANNEL) & my other channel is RC EXPERIMENTS HACKER*****
// Metal objects near search loop change inductance.
// ADC reading depends on inductance.
// changes wrt long-running mean are indicated by LEDs
// LED1 indicates a rise in inductance
// LED2 indicates fall in inductance
// the flash rate indicates how large the difference is

// wiring:
// 220Ohm resistor on D2
// 10-loop D=10cm seach loop between ground and resistor
// diode (-) on pin A0 and (+) on loop-resistor connection
// 10nF capacitor between A0 and ground
// LED1 in series with 220Ohm resistor on pin 8
// LED2 in series with 220Ohm resistor on pin 9


const byte npulse = 3;
const bool sound = true;
const bool debug = false;

const byte pin_pulse=A0;
const byte pin_cap  =A1;
const byte pin_LED1 =12;
const byte pin_LED2 =11;
const byte pin_tone =10;

void setup() {
  if (debug) Serial.begin(9600);
  pinMode(pin_pulse, OUTPUT); 
  digitalWrite(pin_pulse, LOW);
  pinMode(pin_cap, INPUT);  
  pinMode(pin_LED1, OUTPUT);
  digitalWrite(pin_LED1, LOW);
  pinMode(pin_LED2, OUTPUT);
  digitalWrite(pin_LED2, LOW);
  if(sound)pinMode(pin_tone, OUTPUT);
  if(sound)digitalWrite(pin_tone, LOW);
}

const int nmeas=256;  //measurements to take
long int sumsum=0; //running sum of 64 sums 
long int skip=0;   //number of skipped sums
long int diff=0;        //difference between sum and avgsum
long int flash_period=0;//period (in ms) 
long unsigned int prev_flash=0; //time stamp of previous flash

void loop() {

  int minval=1023;
  int maxval=0;
  
  //perform measurement
  long unsigned int sum=0;
  for (int imeas=0; imeas<nmeas+2; imeas++){
    //reset the capacitor
    pinMode(pin_cap,OUTPUT);
    digitalWrite(pin_cap,LOW);
    delayMicroseconds(20);
    pinMode(pin_cap,INPUT);
    //apply pulses
    for (int ipulse = 0; ipulse < npulse; ipulse++) {
      digitalWrite(pin_pulse,HIGH); //takes 3.5 microseconds
      delayMicroseconds(3);
      digitalWrite(pin_pulse,LOW);  //takes 3.5 microseconds
      delayMicroseconds(3);
    }
    //read the charge on the capacitor
    int val = analogRead(pin_cap); //takes 13x8=104 microseconds
    minval = min(val,minval);
    maxval = max(val,maxval);
    sum+=val;
    //determine if LEDs should be on or off
    long unsigned int timestamp=millis();
    byte ledstat=0;
    if (timestamp<prev_flash+10){
      if (diff>0)ledstat=1;
      if (diff<0)ledstat=2;
    }
    if (timestamp>prev_flash+flash_period){
      if (diff>0)ledstat=1;
      if (diff<0)ledstat=2;
      prev_flash=timestamp;   
    }
    if (flash_period>1000)ledstat=0;

    //switch the LEDs to this setting
    if (ledstat==0){
      digitalWrite(pin_LED1,LOW);
      digitalWrite(pin_LED2,LOW);
      if(sound)noTone(pin_tone);
    }
    if (ledstat==1){
      digitalWrite(pin_LED1,HIGH);
      digitalWrite(pin_LED2,LOW);
      if(sound)tone(pin_tone,2000);
    }
    if (ledstat==2){
      digitalWrite(pin_LED1,LOW);
      digitalWrite(pin_LED2,HIGH);
      if(sound)tone(pin_tone,500);
    }
  
  }

  //subtract minimum and maximum value to remove spikes
  sum-=minval; sum-=maxval;
  
  //process
  if (sumsum==0) sumsum=sum<<6; //set sumsum to expected value
  long int avgsum=(sumsum+32)>>6; 
  diff=sum-avgsum;
  if (abs(diff)<avgsum>>10){      //adjust for small changes
    sumsum=sumsum+sum-avgsum;
    skip=0;
  } else {
    skip++;
  }
  if (skip>64){     // break off in case of prolonged skipping
    sumsum=sum<<6;
    skip=0;
  }

  // one permille change = 2 ticks/s
  if (diff==0) flash_period=1000000;
  else flash_period=avgsum/(2*abs(diff));    
    
  if (debug){
    Serial.print(nmeas); 
    Serial.print(" ");
    Serial.print(minval); 
    Serial.print(" ");
    Serial.print(maxval); 
    Serial.print(" ");
    Serial.print(sum); 
    Serial.print(" ");
    Serial.print(avgsum); 
    Serial.print(" ");
    Serial.print(diff); 
    Serial.print(" ");
    Serial.print(flash_period); 
    Serial.println();
  }
  
}


Comments

Post a Comment

Popular posts from this blog

How to make talking Voltmeter at home

Image
 Homemade talking voltmeter using Arduino   It's easy to make a simple digital voltmeter using an Arduino, Audio amplifier and Speaker It's relatively simple to use an Arduino to measure voltages. The Arduino has several analog input pins that connect to an analog-to-digital converter (ADC) inside the Arduino. The Arduino ADC is a ten-bit converter, meaning that the output value will range from 0 to 1023. We will obtain this value by using the analogRead() function. If you know the reference voltage--in this case we will use 5 V--you can easily calculate the voltage present at the analog input.   Requirement 1. Arduino uno/nano. 2. Audio amplifier. 3. Speaker. 4. 100K ohm resistor. 5. battery . Circuit Diagram  Pin mapping table for different platforms    * Platform     Normal      Inverted    8kHz timer  PWM timer  * -------------------------------------------------------  * AVR          3           11          1           2  * ATmega2560   6/PH3       7/PH4       1           
Read more

how to make taking distance measurement device using Arduino and ultrasonic sensor

Image
Homemade Talking measuring Device using Arduino , Ultrasonic and Speaker   Namskar dooston ajke is article me hum sikhenge kaise hum ek distance measurement device banayenge jiske madad se hum kiska bhi distance measure kar sakte hai wo bhi bina touch kiye aur ye device apko bolke batayega distance kitna hai. agar apko project banane me koi bhi problems hota hai iske video jarur dekhe jo apko niche miljayega agar ap video sahise full nahi dekhoge apko kuchh bhi samhme nahi ayega.. Components Required. 1. Arduino Uno or Nano. 2. Mini Amplifier. 3. Speaker. 4. Ultrasonic sensor. 5. Toggle Switch. 6. 3.7V Li-ion Battery. 7. Li-ion battery charger. 8 PVC sheet. CIRCUIT DIAGRAM. Making Video  MAIN ARDUINO CODE. #include <Arduino.h> #include "TalkieUtils.h" #include "Vocab_US_Large.h"  #include "Vocab_Special.h" #include "HCSR04.h" Talkie Voice; const uint8_t ECHO_IN_PIN = 9; const uint8_t TRIGGER_OUT_PIN = 10; void setup()   {     pinMode(LED_BU
Read more

How to make voltmeter using Arduino

Image
ABOUT THIS PROJECT About This project is about the simple hack of voltmeter by Arduino. The main reason behind making this is from my personal experience, when I was performing one experiment in the lab, I could not find a voltmeter so I made this hack to fulfill my requirement and also I think it will help others too. Good project for beginners which uses basic concepts, yet a power full tool. While running the code, you can find the output on the serial monitor. Calculating Voltage Formula for calculating voltage: Vout = (Val * 5.0 ) / 1024.00 ; Here in these formula Val is the value that is read by Arduino as analog input, which is further multiplied by the voltage that is been supplied by Arduino and thus to get the Vout it is divided by the cycle of time that is covered after every bit to get the value. Vin = Vout / ( R2 / R1 + R2 ) By this formula we can find the Vin that will be around 0, which indirectly means we are creating ground. NOTE: Here there is no restriction on usi
Read more